Listing 3: DiskSpaceAllServers.vbs

Option Explicit
On Error Resume Next
Dim objConnection
Dim objCommand
Dim strQuery
Dim objRecordSet
Dim strComputer
Dim SWBemlocator
Dim objWMIService
Dim colItems
Dim objItem

Set objCommand = CreateObject("ADODB.Command")
Set objConnection = CreateObject("ADODB.Connection")
objConnection.Provider = "ADsDSOObject"
objConnection.Open "Active Directory Provider"
objCommand.ActiveConnection = objConnection

strQuery = "<LDAP://dc=mycompany, dc=com>;" & _
  "(&(objectCategory=computer)(operatingSystem=windows*server*));" _
  & "name;subtree"
objCommand.CommandText = strQuery
Set objRecordSet = objCommand.Execute

Do Until objRecordSet.EOF  
  strComputer = objRecordSet.Fields("Name")
  Set SWBemlocator = CreateObject("WbemScripting.SWbemLocator")
  Set objWMIService = _
    SWBemlocator.ConnectServer(strComputer,"\root\CIMV2")
  Set colItems = _
    objwmiservice.ExecQuery("SELECT * FROM Win32_LogicalDisk")
  For Each objItem In colItems
    WScript.Echo strComputer & vbTab & objitem.caption & vbTab _
      & objItem.freespace 
  Next
  objRecordSet.MoveNext
Loop